*******************************************************
* Taiwan Semiconductor
* TSM9409CS_P_MOS
* P-Channel 60V (D-S) Power MOSFET
* Date: 2022-4-15
*******************************************************
.SUBCKT TSM9409CS_P_MOS D G S 
**+params:  EP= {EP} ken651231@yahoo.com.tw
M1 3 GX S S PMOS W= 806000u L= 0.39u 
M2 S GX S D NMOS W= 806000u L= 0.41u 
R1 D 3 86.051e-03 TC=3.880e-03 9.836e-06
CGS GX S 0.468e-09 
CGD GX D 0.155e-10 
RG G GY 9.8
RTCV 100 S 1e6 TC=-0.408e-03 3.016e-6
ETCV GY GX 100 200 1 
ITCV S 100 1u 
VTCV 200 S 1 
DBD D S DBD 
**************************************************************** 
.MODEL PMOS PMOS ( LEVEL = 3 TOX = 5.0e-8 
+ RS = 1.240e-04 KP = 8.012e-06 NSUB = 3.2231e+16 THETA= 0.5 VTO= -1.92
+ KAPPA = 3.800e-03 ETA = 1.644e-07 NFS = 8.003e+11 
+ LD = 0 IS = 0 TPG = -1) 
*************************************************************** 
.MODEL NMOS NMOS ( LEVEL = 3 TOX = 5.0e-8 
+NSUB = 1.387e+16 IS = 0 TPG = -1 ) 
**************************************************************** 
.MODEL DBD D ( 
+FC = 0.1 TT = 3.200e-08 T_MEASURED = 25 BV = 66.88 IBV=250u TBV1=740e-6 TBV2=-1.48u
+RS = 2.6426e-02 N = 1.056e+00 IS = 4.2e-11
+EG = 1.125e+00 XTI = 8.838e-01 TRS1 = 1.000e-05 
+CJO = 1.323e-10 VJ = 3.050e-01 M = 4.322e-01 ) 
****************************************************************
.ENDS